Mod the Machine

Creating Custom Property Sets and iProperties

In all previous iProperty related posts I’ve only talked about working with the four public property sets; Design Tracking, Summary Info, Document Summary Info, and User Defined.  The first three of these contain a fixed number of properties while the user defined allows you to add and delete your own properties.  This mirrors the iProperty functionality that’s available through Inventor’s user-interface.

Using the API it’s possible to create new property sets in addition to these standard four.  A property set created using the API is not visible through the user-interface.  For example, it does not automatically create a new tab in the iProperty dialog.  It is only accessible through the API.  The code below creates a new property set named “MyStuff” and a property named “Favorite Fruit”.

Public Sub CreatePropertySet()
    ' Get the active document.
    Dim doc As Document
    Set doc = ThisApplication.ActiveDocument

    ' Create a new property set.
    Dim customSet As PropertySet
    Set customSet = doc.PropertySets.Add("My Stuff")

    ' Add a property.
    Call customSet.Add("Banana", "Favorite Fruit")
End Sub

Here’s some sample code that accesses and reads the value of the property created above.

Public Sub ReadProperty()
    ' Get the active document.
    Dim doc As Document
    Set doc = ThisApplication.ActiveDocument

    ' Get the custom property set.
    Dim customSet As PropertySet
    Set customSet = doc.PropertySets.Item("My Stuff")

    ' Get the value of the "Favorite Fruit" property.
    Dim fruit As String
    fruit = customSet.Item("Favorite Fruit").value
    MsgBox "The favorite fruit is: " & fruit
End Sub

Hopefully you can see that working with these custom property sets is not any different than working with the standard property sets.  It’s likely that you won’t ever  need for this capability but sometimes it can come in handy.  The primary use is when you need to store additional data with a file.  iProperties especially make sense when you want to be able to access this information from Apprentice.  An example of where Inventor uses this functionality is Content Center.  Content Center adds an new property set to the parts it creates and uses the property set to store information about the part.

A useful tool when working with iProperties is a sample program that’s delivered with the Inventor SDK.  Assuming you’ve installed the developer tools using the DeveloperTools.msi in the SDK directory, you’ll find the following directory:

SDK\DeveloperTools\Samples\VB\Standalone Applications\ApprenticeServer\Properties

It’s an old VB6 sample, but you can use the EXE without having VB6.  When you run the EXE, the dialog below is displayed.  You use the button at the top to browse to any Inventor file.  The property sets and properties are then displayed in the dialog and you can double-click on most properties to edit them.  I use tool anytime I want to know about all of the iProperties in a document.

iProperties and Dates

 
The previous post on working with custom iProperties shows how to create iProperties of various types, including dates.  However, dates have one unique behavior, as shown below.  There is a check box next to each date property, (circled in the picture below), that the user can check or uncheck to indicate if they want to set a date or not.

A date iProperty will always have a value, but there is one date that is considered the zero date.  If you set the iProperty value to this date it will have the side-effect of removing the check from the box.  The date is Jan. 1, 1601.  The code below demonstrates creating two new custom iProperties.  One will be set to the zero date and the other will be set to the current date.

Public Sub DateProperties()
    Dim partDoc As PartDocument
    Set partDoc = ThisApplication.ActiveDocument

    ' Get the custom property set.
    Dim customPropSet As PropertySet
    Set customPropSet = partDoc.PropertySets.Item( _
                                "Inventor User Defined Properties")

    ' Create the properties.
    Dim dateValue As Date
    dateValue = #1/1/1601#
    Dim sample1 As Property
    Set sample1 = customPropSet.Add(dateValue, "Zero Date")

    dateValue = Now
    Dim sample2 As Property
    Set sample2 = customPropSet.Add(dateValue, "Now Date")
End Sub

Here’s the result after running the program.  Notice that the check box for the zero date property is unchecked.

This is also important to understand if you ever need to read the value of a date property.  In the example above, the date for the Zero Date iProperty will be Jan. 1, 1601, but you should handle this date as a special case and treat it as though the date hasn’t been set.

iProperty Expressions

In the iProperties dialog, Inventor allows you to create expressions for the values of iProperties.  Using an expression you can combine the values of other iProperties into a single iProperty value.  (By using the functionality described in a previous post to create an iProperty for a parameter, you can also use parameter values in an expression.)  To create an expression just enter an “=” sign as the first character of the iProperty value.  Inventor will now treat this as an expression.  An expression can consist of any text and can reference any existing iProperties by specifying their names in brackets, as shown below.  The expression in this example uses the iProperty named “Part Number” and two custom iProperties named “Length” and “Height” that were created by exporting parameters.

Once you’ve finished entering the expression and press return, the expression is evaluated and the resulting value is displayed, as shown below. 

The symbol to the right of the field indicates that the property is defined using an expression.  To edit the expression, rather than the value, right-click in the iProperty field and select the Edit Expression command from the context menu, as shown below.

To use expressions through the API you use the Expression property of the Property object.  This is demonstrated below.  The Expression property is the equivalent of editing the expression in the iProperties dialog.  When setting the value of the Expression property you need to follow the same rules as when creating an expression in the iProperties dialog.  The Value property of the Property object will always return the evaluated result.  Setting the value through the Value property will remove the expression associated with the property or you can set the value of the expression to an empty string (“”).

Public Sub TestExpression()
    Dim partDoc As PartDocument
    Set partDoc = ThisApplication.ActiveDocument

    ' Get the Design Tracking property set.
    Dim designTrackPropSet As PropertySet
    Set designTrackPropSet = partDoc.PropertySets.Item( _
                                     "Design Tracking Properties")

    ' Get the Description property.
    Dim descProp As Property
    Set descProp = designTrackPropSet.Item("Description")

    ' Add an expression to the property.
    descProp.Expression = _
                     "=<Part Number> size is <Length> x <Height>"
End Sub

The program below removes the expression from the property but maintains the property’s current value.  It does this by setting the value of the property to its current value.  This would at first seem like it wouldn’t do anything, but in the case where the property is defined using an expression, setting the value of the property removes the expression.  It’s just that in this case the value we’re setting it to happens to be the current displayed value.

Public Sub TestExpression()
    Dim partDoc As PartDocument
    Set partDoc = ThisApplication.ActiveDocument

    ' Get the Design Tracking property set.
    Dim designTrackPropSet As PropertySet
    Set designTrackPropSet = partDoc.PropertySets.Item( _
                                     "Design Tracking Properties")

    ' Get the Description property.
    Dim descProp As Property
    Set descProp = designTrackPropSet.Item("Description")

    ' Set the value of the property to it’s current value.
    ' This has the side-effect of removing an associated expression.

    descProp.Value = descProp.Value
End Sub

Parameters as iProperties

The next few posts I’ll be making are intended to complete my coverage of topics related to iProperties.  I’ve made several recent posts that I believe cover the majority of the API functionality that will enable you to write most programs that use iProperties.  However, there are a few odds and ends that I haven’t covered.  Here’s the first of these last set of posts on iProperties.

In the Parameters dialog you can check the Export Parameter box for a parameter, as shown circled below.  This is useful because there are quite a few areas in Inventor that provide access to property values, (text in drawings, BOM, etc.), and by exporting a parameter as a property it extends the use of the existing functionality to also be able to use parameters.

This causes a custom iProperty to be created that contains the value of that parameter.  This is a one-way association.  Changing the parameter will cause the iProperty to update, but changing the value of the iProperty will not cause the parameter to update.  The iProperty is just a reflection of the parameter and will be updated whenever the parameter value changes.

If the Export Parameter box is checked, then you can also access the Custom Property Format… command through the context menu, as shown below.

This displays the dialog shown below where you can control the format of the iProperty that’s created for this parameter.

This all results in the iProperty shown below.  The name of the iProperty is the same as the parameter.  If an iProperty of that name already exists, it’s value will be overwritten to the value of the parameter.  You can edit and even delete the iProperty, but Inventor will overwrite the edited value or re-create the iProperty whenever the parameter value changes.

From the API you can also set the “Export Parameter” box for a parameter.  You do this by using the ExposedAsProperty property of the Parameter object.  With Inventor 2010 and later you can also edit the formatting of the resulting iProperty using the CustomPropertyFormat property of the Parameter object.  This is demonstrated in the code below.

Dim param As Parameter
Set param = partDoc.ComponentDefinition.Parameters.Item("Length")
param.ExposedAsProperty = True

param.CustomPropertyFormat.Precision = kThreeDecimalPlacesPrecision
param.CustomPropertyFormat.ShowTrailingZeros = True
param.CustomPropertyFormat.ShowUnitsString = True
param.CustomPropertyFormat.Units = "in"

iProperties created as the result of an export appear like any other property through the API.  In fact, the iProperty doesn’t know it’s the result of an export.  If you need to find the iProperties that were created through an export you’ll would need to look through the parameters to see if any of them have been exported.