Mod the Machine

Self-Pace Inventor API Development Guide

The Autodesk Developer Network (ADN) has recently released a self-paced guide for Inventor API development called “My First Plug-in”.  The guide is designed for those of you that are new to programming and doesn’t assume any previous programming experience.  Most of the content discusses basic programming concepts and then lets you put them into practice utilizing Inventor’s API (Application Programming Interface) to create a simple program to control the display of occurrences within an assembly.

Even for those of you that are experienced Inventor API developers, if you’ve been using VBA this will serve as a good introduction to VB.Net.  It uses Visual Basic Express, which is available as a free download from Microsoft.

Clicking the picture below will take you to the “My First Plug-In Training” page for Inventor.  There is also a similar tutorial for Revit.

Writing Work Points to an Excel File

Here’s a solution to another problem that was recently posed.  A customer is creating work points in a part and then needs an Excel file that has the coordinates of the work points.  Here’s a VBA macro that will create a .csv file that contains the coordinates of the work points.  If you select any work points before running the macro, it will give you the option of exporting only the selected work points or exporting all of the work points.  If no work points are selected, then it will export all work points.  Let me know if you find any issues or have suggestions on how to improve it.

Update: Since I first posted this I received a question about how to have the macro use the current length units of the document.  I’ve modified it so it now does that.  Previously it was using the internal length unit of centimeters.  It now uses the length specified for the document, but it ignores the number of decimal places specified for the document and always writes out up to 8 decimal places.

Public Sub ExportWorkPoints()
    ' Get the active part document.
    Dim partDoc As PartDocument
    If ThisApplication.ActiveDocumentType = kPartDocumentObject Then
        Set partDoc = ThisApplication.ActiveDocument
    Else
        MsgBox "A part must be active."
        Exit Sub
    End If
   
    ' Check to see if any work points are selected.
    Dim points() As WorkPoint
    Dim pointCount As Long
    pointCount = 0
    If partDoc.SelectSet.Count > 0 Then
        ' Dimension the array so it can contain the full
        ' list of selected items.
        ReDim points(partDoc.SelectSet.Count - 1)
       
        Dim selectedObj As Object
        For Each selectedObj In partDoc.SelectSet
            If TypeOf selectedObj Is WorkPoint Then
                Set points(pointCount) = selectedObj
                pointCount = pointCount + 1
            End If
        Next
       
        ReDim Preserve points(pointCount - 1)
    End If
   
    ' Ask to see if it should operate on the selected points
    ' or all points.
    Dim getAllPoints As Boolean
    getAllPoints = True
    If pointCount > 0 Then
        Dim result As VbMsgBoxResult
        result = MsgBox("Some work points are selected.  " & _
                "Do you want to export only the " & _
                "selected work points?  (Answering " & _
                """No"" will export all work points)", _
                vbQuestion + vbYesNoCancel)
        If result = vbCancel Then
            Exit Sub
        End If
   
        If result = vbYes Then
            getAllPoints = False
        End If
    Else
        If MsgBox("No work points are selected.  All work points" & _
                  " will be exported.  Do you want to continue?", _
                  vbQuestion + vbYesNo) = vbNo Then
            Exit Sub
        End If
    End If
   
    Dim partDef As PartComponentDefinition
    Set partDef = partDoc.ComponentDefinition
    If getAllPoints Then
        ReDim points(partDef.WorkPoints.Count - 2)
       
        ' Get all of the workpoints, skipping the first,
        ' which is the origin point.
        Dim i As Integer
        For i = 2 To partDef.WorkPoints.Count
            Set points(i - 2) = partDef.WorkPoints.Item(i)
        Next
    End If
   
    ' Get the filename to write to.
    Dim dialog As FileDialog
    Dim filename As String
    Call ThisApplication.CreateFileDialog(dialog)
    With dialog
        .DialogTitle = "Specify Output .CSV File"
        .Filter = "Comma delimited file (*.csv)|*.csv"
        .FilterIndex = 0
        .OptionsEnabled = False
        .MultiSelectEnabled = False
        .ShowSave
        filename = .filename
    End With
   
    If filename <> "" Then
        ' Write the work point coordinates out to a csv file.
        On Error Resume Next
        Open filename For Output As #1
        If Err.Number <> 0 Then
            MsgBox "Unable to open the specified file. " & _
                   "It may be open by another process."
            Exit Sub
        End If
       
        ' Get a reference to the object to do unit conversions.
        Dim uom As UnitsOfMeasure
        Set uom = partDoc.UnitsOfMeasure
       
        ' Write the points, taking into account the current default
        ' length units of the document.
        For i = 0 To UBound(points)
            Dim xCoord As Double
            xCoord = uom.ConvertUnits(points(i).Point.X, _ 
                 kCentimeterLengthUnits, kDefaultDisplayLengthUnits)
                    
            Dim yCoord As String
            yCoord = uom.ConvertUnits(points(i).Point.Y, _ 
                 kCentimeterLengthUnits, kDefaultDisplayLengthUnits)
                    
            Dim zCoord As String
            zCoord = uom.ConvertUnits(points(i).Point.Z, _ 
                 kCentimeterLengthUnits, kDefaultDisplayLengthUnits)
                    
            Print #1, points(i).Name & "," & _
                Format(xCoord, "0.00000000") & "," & _
                Format(yCoord, "0.00000000") & "," & _
                Format(zCoord, "0.00000000")
        Next
       
        Close #1
       
        MsgBox "Finished writing data to """ & filename & """"
    End If
End Sub

Moving a Part in a Flexible Assembly

I recently received a question that I thought there might be some general interest in the answer.  Here’s the problem.  I have the assembly shown below.  It’s free to move in the ways you would expect; it can pivot about the base and the arm can extend.  Everything is fine so far.

Next I insert the arm assembly shown above into a new assembly.  Then I insert the yellow block part into the assembly and constrain it to the tip of the arm, as shown below.

First, the arm assembly is rigid if I try to move any of its parts.  That’s the behavior I would expect because, by default, subassemblies are rigid within an assembly.  However, you can set the subassembly occurrence to be “flexible” so that it will behave the same as it does when the subassembly is active.  That is, the arms can be dragged and the positions of all of the connected parts will update.  I can also drag the yellow block and that will cause the arms to reposition to follow the block.

The question posed was how to move the block using the API and still get the arms to follow.  The expectation, which I shared, is that setting the transformation for the yellow block to reposition it should automatically reposition everything else that’s connected to it.  This is probably how it should behave but it’s not.  When setting the position of the yellow block nothing happens.  The yellow block doesn’t move and the arm subassembly doesn’t move.

I played around with a couple of ideas and one of them does work.  It’s simple to implement so should be an acceptable workaround.  It temporarily grounds the part that’s being moved.  The API to move a part will move a grounded part and when the assembly computes, the grounded part has a higher priority in the solver than the flexible assembly so the flexible assembly adjusts to the change.

Here’s the code I used to test this.

Public Sub MovePart()
    ' Have the occurrence that will be moved selected.
    Dim occ As ComponentOccurrence
    Set occ = ThisApplication.CommandManager.Pick( _ 
                                       kAssemblyOccurrenceFilter, _ 
                                       "Select an occurrence.")

    ' Get the current grounded state of the selected occurrence. 
    Dim groundState As Boolean
    groundState = occ.Grounded
   
    ' Ground the occurrence.
    occ.Grounded = True
   
    ' Change the position of the occurrence.  This repositions it
    ' in a series of steps to create a short animation.  It moves
    ' it 0.5 cm in the Y direction for each step.
    Dim i As Integer
    For i = 1 To 10
        Dim trans As Matrix
        Set trans = occ.Transformation
        trans.Cell(2, 4) = trans.Cell(2, 4) + .5
        occ.Transformation = trans
    Next

    ' Reset the grounded state of the occurrence back to
    ' its original state.
    occ.Grounded = groundState
End Sub

Last Chance for Input

The Inventor API survey has been extended.  You now have until June 17th to provide your input.  This helps us a lot in determining what we’re going to do in upcoming releases so please give us your opinion on what’s important.

http://www.zoomerang.com/Survey/WEB22C9QBPTEZ5

Correction to Feature Stepper Macro

I’ve just corrected a problem to the code from my previous post for the macro that steps through the features in a part.  It just shows you that I didn’t test if very thoroughly.  The previous version only works on sheet metal parts.  The new version works on regular parts too.  If you already got the code, you just need to download the zip file, unpack it, delete the form from your VBA project, and re-import the form file.

Stepping Through the Features of a Model

A recent question came in about a way to make it easy to step through the features in the browser.  Of course you can do this manually by dragging the stop node feature-by-feature in the tree, but that quickly becomes tedious.  Here’s my answer to problem.  It’s a small VBA program that displays a form as shown below.

Pressing the buttons let’s you move the stop node to the top, to the bottom, or advanced it one step at a time, either up or down the tree.  A utility like this can be useful when you’ve received a model from someone else and want to understand how it was built.

I think the trickiest part about using this program will be adding it to your VBA project.  Fortunately you only have to do that once.  Below is the step-by-step process to add it to your default VBA project and create a button in the ribbon to execute it.

1. Download and unzip the code files.  You can unzip them anywhere on your computer.
2. Run Inventor and open the VBA development environment, (Alt-F11).
3. Right-click on the “ApplicationProject” node in the Project window and select “Import File…”, as shown below.
   
   
   
4. Select the “FeatureStep.frm” file that you unpacked previously from the zip file.
   
   
5. In the VBA project window, double-click on Module1, within the Modules folder.  This will open up the code window. 
   
   
   
6. Copy and paste the code below into that window, as shown above.
   

   ' Macro to reposition stop node in browser.
   Public Sub FeatureStep()
       Dim featureStepForm As New frmFeatureStep
       If featureStepForm.Init Then
           featureStepForm.Show vbModeless
       End If
   End Sub  
   

7. The following steps will create a button on the ribbon to run the macro.  Have a part open, making sure you’re in the modeling environment and a sketch is not active.  Right-click anywhere on the ribbon and select the “Custom User Commands…” command from the context menu, as shown below.
   
   
   
8. In the Customize dialog, first choose “Macros” in the “Choose commands from” drop-down.  Next, select the “FeatureStep” macro from the list.  (If it’s not in the list, double-check that you followed the previous steps correctly.)  Finally, click the “>>” button to move that macro the to the right side of the dialog.
   
   
   
9. Edit the settings on the button to display text.
   
   
   
   You should see the following in the ribbon.  If you want the command available on the Sheet Metal modeling ribbon, you’ll need to repeat steps 6 through 8 while a sheet metal document is open.
   
   

Inventor API Survey

It’s time once again to make your voice heard.  The annual Inventor API survey has begun and is all about getting your input about what API functionality we should be working on for future Inventor releases.  The questions this year a little more specific than they’ve been in the past.  Hopefully, this will help us to be able to more clearly define the areas where there’s the most need.  If there’s something you need and it’s not listed, please feel free to list it.  Just click the link below to go to Kean Walmsley’s blog post for the link to survey and more information.

Inventor API Survey

Thank you for participating.

Saving 3D DWG Using the DWG Translator

Some new functionality in Inventor 2012 is the ability to save 3D part and assembly models to a DWG file.  Ok, this isn’t exactly new but the previous way to do it was a bit of a workaround by using the AEC Exchange application (now known as BIM Exchange) to create the DWG file.  In Inventor 2012 the DWG translator has been expanded to support 3D so you can use the Save Copy As command and select “AutoCAD DWG Files” as the file type.  In the options dialog you can choose which of the following types to write out; Solid, Surface, or Sketch.  You can also specify which version of DWG you want to create; 2000, 2004, 2007, or 2010.

It’s also possible to do the same thing through the API by controlling the DWG translator add-in as shown below.  The result of running the VBA macro below is that it will save the solids in the active part or assembly as an AutoCAD 2010 DWG file called “C:\Temp\DWGOutTest.dwg”.  The options are documented in the comments.

Public Sub SaveCopyAsDWG3D()
    ' Get the DWG translator Add-In. 
    Dim DWGAddIn As TranslatorAddIn
    Set DWGAddIn = ThisApplication.ApplicationAddIns.ItemById( _
                         "{C24E3AC2-122E-11D5-8E91-0010B541CD80}")

    ' Get the active document.  Can be either a part or assembly.
    Dim doc As Document 
    Set doc = ThisApplication.ActiveDocument 

    Dim transObjs As TransientObjects
    Set transObjs = ThisApplication.TransientObjects

    ' Set up the context to define an output file.
    Dim context As TranslationContext
    Set context = transObjs.CreateTranslationContext
    context.Type = kFileBrowseIOMechanism

    ' Get the available options from the translator.
    Dim options As NameValueMap
    Set options = transObjs.CreateNameValueMap
    If DWGAddIn.HasSaveCopyAsOptions(doc, context, options) Then
        ' Set the options for what types of data to write out. 
        options.Value("Solid") = True      ' Output solids. 
        options.Value("Surface") = False   ' Output surfaces. 
        options.Value("Sketch") = False    ' Output sketches.
       
        ' Set the DWG version.
        ' 23 = ACAD 2000
        ' 25 = ACAD 2004
        ' 27 = ACAD 2007
        ' 29 = ACAD 2010 
        options.Value("DwgVersion") = 29
    End If

    ' Set the output filename, using a DataMedium object.
    Dim oDataMedium As DataMedium
    Set oDataMedium = transObjs.CreateDataMedium
    oDataMedium.filename = "c:\temp\DWGOutTest.dwg"

    ' Call the SaveCopyAs method of the translator add-in.
    Call DWGAddIn.SaveCopyAs(doc, context, options, oDataMedium)
End Sub

Inventor 2012

Inventor 2012 has been announced and you’ve probably seen various press reports on some of the new features.  Inventor 2012 also a lot of new functionality in the API.  You can find a presentation of what’s new in the API, along with some samples on the http://www.autodesk.com/developinventor website.  An updated object model chart is also available there.

There will also be a live showing of this presentation on April 7th, where I’ll be going through the same presentation you can download above.  It’s free and you can sign up for the webcast at ADN Course Schedule page.  Look for the class titled “DevDays Online: Inventor 2012 API updates” and click the “Register” link.

Recommended Books

With Sanjay moving onto another job and also some other additional responsibilities, I’ve been very busy lately.  Part of the other work I’ve been doing has involved quite a bit of code writing.  I want to point out a couple of books that I have that I keep going to back to for reference.  You have to keep in mind that the primary target audience for these books is someone coming from VB6 and moving to VB.Net, which is my background, so I’m not sure how useful all of you will find these, but I found them well worth the money.

I would also like to hear what books you’ve found useful.  A category of book where I don’t have much experience are those for beginning programmers and would especially like to know if any of you have found books in this category that you would recommend.  Here are the books I can recommend:

The .NET Languages: A Quick Translation Guide by Brian Bischof
I found this book the most useful when I was first transitioning to VB.Net.  It lists common functionality in VB6 and compares it with the equivalent functionality in both VB.Net and C#.

Used and new copies are available on Amazon for about $5, including postage.

Programming Microsoft Visual Basic .Net by Francesco Balena
I got my copy of this book in the early days of VB.Net  There’s been one updated edition since then for VB.Net 2003 but the content still applies.  It’s a massive book at over 1500 pages and has answered most of my questions when I need to do something in VB.Net that I haven’t done before.  This is the book that I keep by my keyboard and turn to the most now.

Used copies of this book are also available on Amazon for a good deal.  The only problem with the used copies is that a lot of them may not come with the included CD.  I glanced at the CD content when I first got the book but haven’t used it since then so I’m not sure how useful it is, but if you have a choice you just as well get a copy that contains the CD.